m4_divert(-1)

_
_ <pysrcs>
_
m4_divert(5)
m4_srclist(PYDIST_PY_SRCS)
m4_srcitem($(PYDIST_SYSCFG_SRCS))
m4_divert(-1)

m4_define([PYCDIR],[_
m4_ifelse([$1],[],_
[m4_divert(1)]_
m4_srclist([PYDIST_SRCS])
[m4_divert(-1)],_
[$2],[1],_
[m4_divert(1)]_
m4_srclist([PYDIST_]m4_pathvar([$1][_SRCS]))
[m4_divert(-1)])_
_
m4_divert(2)_
m4_ifelse([$1],[],
[m4_divert(-1)],
m4_tab[mkdir -p $(PYDIST_PYCDIR)/./][$1])
_
m4_divert(3)_
m4_ifelse([$1],[],
m4_rightalign(64,[$(PYDIST_PYCDIR)/./][%.py:])[pydist.tag],_
m4_rightalign(64,[$(PYDIST_PYCDIR)/./][$1]/[%.py:])[pydist.tag])
_
m4_divert(4)
m4_ifelse([$1],[],
[$(PYDIST_PYCDIR)/./][%.py: \]
m4_tabtabtab([$(SOURCE_DIR)/Lib/./][[$1]][%.py pydist.tag]),
[$(PYDIST_PYCDIR)/./][$1]/[%.py: \]
m4_tabtabtab([$(SOURCE_DIR)/Lib/./][[$1]]/[%.py pydist.tag]))
m4_tabtab[PYCOPY_PYTHON=$(PYCOPY_PYTHON) \]
m4_tabtab[PYCOPY_PREFIX=$(PYCOPY_PREFIX) \]
m4_tabtab[PYCOPY_DSTDIR=$(PYDIST_PYCDIR)/./][$1] \
m4_tabtab[$(PYCOPY) $<]
_
m4_ifelse([$1],[],_
[m4_divert(5)]_
m4_srcitem([$(PYDIST_SRCS)])
[m4_divert(-1)],
[$2],[1],_
[m4_divert(5)]_
m4_srcitem([$(PYDIST_]m4_pathvar([$1][_SRCS)]))
[m4_divert(-1)])
_
m4_divert(6)_
m4_tab[mkdir -p $(DESTDIR)/$(LIBDIR)/$(PACKAGE)/./][$1]
m4_divert(-1)
_
m4_ifelse([$1],[],_
[m4_divert(7)]_
m4_tab[]_
m4_rightalign(64,[cp -p $(PYDIST_SRCS)])_
[$(DESTDIR)/$(LIBDIR)/$(PACKAGE)/./]
[m4_divert(-1)],
[$2],[1],_
[m4_divert(7)]_
m4_tab[]_
m4_rightalign(64,[cp -p $(PYDIST_]m4_pathvar([$1][_SRCS)]))_
[$(DESTDIR)/$(LIBDIR)/$(PACKAGE)/./][$1]
[m4_divert(-1)])
_
m4_ifelse([$1],[],_
[m4_divert(8)]_
m4_tab[]_
m4_rightalign(68,[cp -p $(PYDIST_SRCS:%.py=%.pyc)])_
[$(DESTDIR)/$(LIBDIR)/$(PACKAGE)/./]
[m4_divert(-1)],
[$2],[1],_
[m4_divert(8)]_
m4_tab[]_
m4_rightalign(68,[cp -p $(PYDIST_]m4_pathvar([$1][_SRCS])[:%.py=%.pyc)])_
[$(DESTDIR)/$(LIBDIR)/$(PACKAGE)/./][$1]
[m4_divert(-1)])
])


m4_define([PYCSRC],[_
m4_divert(1)_
m4_srcitem($(PYDIST_PYCDIR)/./[$1])]_
m4_divert(-1))
_
_ </pysrcs>
_


_
_ <pydist.tag>
_
m4_divert(2)
pydist.tag:
m4_divert(-1)
_
m4_m4wrap([_
m4_divert(2)_
m4_tab[touch pydist.tag]
m4_divert(-1)_
])
_
_ </pydist.tag>
_


m4_divert(3)
m4_divert(4)

_
_ <pydist-install-tree>
_
m4_divert(6)
pydist-install-tree:
m4_divert(-1)
_
_ </pydist-install-tree>
_


_
_ <pydist-install-py>
_
m4_divert(7)
pydist-install-py: $(PYDIST_PY_SRCS)
pydist-install-py: pydist-install-tree
pydist-install-py:
m4_tab[]_
m4_rightalign([64],[cp -p $(PYDIST_SYSCFG_SRCS)])_
[$(DESTDIR)/$(LIBDIR)/$(PACKAGE)]
m4_divert(-1)
_
_ <pydist-install-py>
_


_
_ <pydist-install-pyc>
_
m4_divert(8)
pydist-install-pyc: $(PYCGEN_OBJS)
pydist-install-pyc: pydist-install-tree
pydist-install-pyc:
m4_tab[]_
m4_rightalign(68,[cp -p $(PYDIST_SYSCFG_SRCS:%.py=%.pyc)])_
[$(DESTDIR)/$(LIBDIR)/$(PACKAGE)]
m4_divert(-1)
_
_ <pydist-install-py>
_


m4_divert(-1)